Извлечение текста. Пример использования

При открытии элемента справочника, для удобства отладки, будем отображать извлеченный текст. 

 

Функционал по прикреплению файла реализован в форме элемента справочника. По команде "ПрикрепитьФайл" вызывается диалог выбора файла. Когда файл выбрать, его двоичные данные помещаются в реквизит "ДокументХранилище", а извлеченный текст в реквизит "ИзвлеченныйТекст". Извлечение текста происходит с помощью общего объекта "ИзвлечениеТекста". На следующем листинге показан код описанной команды:

&НаКлиенте
Процедура ПрикрепитьФайл(Команда)  
	// Файл может быть прикреплен только для уже записанного элемента справочника
	Если Параметры.Ключ.Пустая() Тогда
		Сообщить("Сначала нужно записать элемент!");
		Возврат;
	КонецЕсли;
	// Выбираем файл на диске 
	Режим = РежимДиалогаВыбораФайла.Открытие;
	ДиалогОткрытияФайла = Новый ДиалогВыбораФайла(Режим);
	ДиалогОткрытияФайла.ПолноеИмяФайла = "";
	ДиалогОткрытияФайла.МножественныйВыбор = Ложь;
	ДиалогОткрытияФайла.Заголовок = "Выберите файл";
	Если ДиалогОткрытияФайла.Выбрать() Тогда
		ПутьКФайлу = ДиалогОткрытияФайла.ПолноеИмяФайла;
		// Формируем данные для записи 
		ПараметрыЗаписи = Новый Структура;
		// Двоичные данные файла
		ПараметрыЗаписи.Вставить("Файл", 	Новый ДвоичныеДанные(ПутьКФайлу)); 
		ИзвлеченныйТекст = Новый ИзвлечениеТекста(ПутьКФайлу);
		// Получаем текст документа
		ПараметрыЗаписи.Вставить("Текст", 	ИзвлеченныйТекст.ПолучитьТекст()); 
		// Получаем имя файла без пути
		ПараметрыЗаписи.Вставить("ИмяФайла",СтрЗаменить(ДиалогОткрытияФайла.ПолноеИмяФайла, ДиалогОткрытияФайла.Каталог, ""));
		ЗаписатьДанные(ПараметрыЗаписи);
	Иначе
		Текст = "ru = ""Файл не выбран!""; en = ""File not selected!""";
		Предупреждение(НСтр(Текст));
	КонецЕсли;       	
КонецПроцедуры     
&НаСервере
Процедура ЗаписатьДанные(ПараметрыЗаписи)
	// Конвертируем объект формы в объект справочника
	ОбъектЭлемент = РеквизитФормыВЗначение("Объект");
	// Записываем двоичные данные в хранилище значения
	ОбъектЭлемент.ДокументХранилище = Новый ХранилищеЗначения(ПараметрыЗаписи.Файл);
	// Записываем извлеченный текст
	ОбъектЭлемент.ИзвлеченныйТекст = ПараметрыЗаписи.Текст;
	// Внаименование записываем имя файла
	ОбъектЭлемент.Наименование = ПараметрыЗаписи.ИмяФайла;
	ОбъектЭлемент.Записать();	// Записываем элемент и возвращаем его в объект формы
	ЗначениеВРеквизитФормы(ОбъектЭлемент, "Объект");	
КонецПроцедуры

 У объекта "ИзвлечениеТекста" есть несколько методов:

1. "ПолучитьТекст" - получает текст из файла, на основе которого создан экземпляр объекта.
2. "Записать" - записывает полученный текст в файл.

 

В форме элемента справочника также содержится команда "Открыть файл", извлекающая двоичные и записывающие в файл на диске. После команда запускает приложение для открытия файла, установленное поумолчанию в ОС. Листинг программного кода этой команды приведен на следующем листинге:

&НаКлиенте
Процедура ОткрытьФайл(Команда)
	// Получаем путь к временному файлу
	ПутьФайл = ПолучитьИмяВременногоФайла(Объект.Наименование);
	// Извлекаем двоичные данные из элемента справочника
	Данные = ПолучитьДанные();
	// Записываем файл на диск
	Данные.Записать(ПутьФайл);
	// Открываем файл с помощью приложения, назначенного поумолчанию в операционной системе
	ЗапуститьПриложение(ПутьФайл);                                                         	
КонецПроцедуры
&НаСервере
Функция ПолучитьДанные()   	
	ОбъектЭлемент = РеквизитФормыВЗначение("Объект");
	Возврат ОбъектЭлемент.ДокументХранилище.Получить(); 	
КонецФункции

 Перейдем к реализации поиска по содержимому прикрепленных файлов.

// СтрокаПоиска - строка, которую необходимо найти в содержимом документов
// Второй паарметр - размер одной порции найденных данных
РезультатыПоиска = ПолнотекстовыйПоиск.СоздатьСписок(СтрокаПоиска, 10);